=ВПР("*"&B2&"*";стих!$B$2:$B$21;1;0)

KL
[MVP - Microsoft Excel]

DeggasadНе знай я про ВПР() сам бы так сделал. Оно ещё не известно как лучше?
ВПР() однозначно быстрее, возможно в разы :-)

а смысл данной операции в чем (в контексте предыдущей задачи)?

Если нужно проще и универсальнее то так (см. приложение)

KL
[MVP - Microsoft Excel]

_slan_по-моему уже не раз обсуждалось..

{=МИН(ЕСЛИ(ПСТР(A1;СТОЛБЕЦ(СМЕЩ($A$1;0;0;1;ДЛСТР(A1)));1)>="А";СТОЛБЕЦ(СМЕЩ($A$1;0;0;1;ДЛСТР(A1)));99999))}
При длине слов приведенной в примере...

Значительно короче (66 vs. 105) и быстрее на 25% в XL2007 в 1500 ячейках:
{=ПОИСКПОЗ(ИСТИНА;ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1)>="А";0)}

Вот так уже не требует ввода через CTRL+SHIFT+ENTER, скорость та же и короче (76 vs. 105):
=ПОИСКПОЗ(ИСТИНА;ИНДЕКС(ПСТР(A1;СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1)>="А";0);0)

Не требует ввода через CTRL+SHIFT+ENTER, не летучая, медленнее на 8.5% и все еще короче (89 vs. 105):
=ПОИСКПОЗ(ИСТИНА;ИНДЕКС(ПСТР(A1;СТРОКА(ИНДЕКС(A:A;1):ИНДЕКС(A:A;ДЛСТР(A1)));1)>="А";0);0)

При возрастании длины слов, все три приведенные формулы значительно опережают формулу предложенную _slan_ по скорости пересчета в XL2007 (например: при длине в 43 знака, последняя формула на 18% быстрее в 1500 ячейках)

Deggasad Сергей06Как формулой найти последний символ "\" в таких строках:


количество слешей может быть произвольным...
Задача: разделить путь к файлу на путь папки и сам файл.
или только макросом?

Например так
=ПРАВСИМВ(A1;ДЛСТР(A1)-ПОИСК("|||";ПОДСТАВИТЬ(A1;"\";"|||";ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;"\";"")))))

Еще:
=ПСТР(A1;НАЙТИ("|";ПОДСТАВИТЬ(A1;"\";"|";ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;"\";""))))+1;30000)

A-NikНу что, разобрался ? Помощь нужна ? ;-)

Пока Сергей06 думает, у меня появилась очередная задача, с которой справиться не удалось! :(( Есть массив N x M. Надо получить массив сумм столбцов массива :-)
Массив в диапазоне или получен формулой?

Вот примеры на скорую руку

KL
[MVP - Microsoft Excel]

DaniilKЗадача 361

Есть формула с использованием СУММПРОИЗВ(), которая занимается тем, что подсчитывает на основании нескольких условий.
Хочется упростить формулу в части ЕСЛИ($D$119=0;--(ДЛСТР($D$3:$D$116)>0);--($D$3:$D$116=$D$118)).
Смысл в том, что если в D119 ноль, то условие $D$3:$D$116=$D$118 никак не принималось бы во внимание.
Без CTRL+SHIFT+ENTER:
=СУММПРОИЗВ(--($C$3:$C$116=$C$118);(($D$3:$D$116=$D$118)+($D$119=0))^($D$119<>0);--($E$3:$E$116=$E121);$F$3:$F$116)

С CTRL+SHIFT+ENTER:
{=СУММ(($C$3:$C$116=$C$118)*ЕСЛИ($D$119=0;1;$D$3:$D$116=$D$118)*($E$3:$E$116=$E121)*$F$3:$F$116)}

DaniilKСпасибо Большое!!!
а какая формула предпочтительнее по скорости работы?
Вторая.