Наверное, чтобы не зависеть от кол-ва повторенных символов, лучше так:

=ПОДСТАВИТЬ(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A1;" ";"|");"/";" "));" ";"/");"|";" ")&"/"

KL
[MVP - Microsoft Excel]

DaniilKа что такое "|" ?...

Это любой символ, который заведомо не встречается в исходном тексте.

DaniilKа зачем в конце & ?
это именно для этого частного случая?

Конечно, решение основано на твоем примере. Слэш на конце или должен быть или не должен. Или возможны еще варианты?

СЖПРОБЕЛЫ действует не так, как ты думаешь :-)

Эта функция делает следующее:
1) уничтожает все пробелы в начале строки
2) уничтожает все пробелы в конце строки
3) заменяет все остальные скопления пробелов на один пробел

KL
[MVP - Microsoft Excel]

DaniilKвот мой ответ:

"буду знать...
я тут у одного человека в аське пытался это спросить, его не было, а вот сейчас он прислал ответ (он раньше общался тоже на форумах об Эксель, ник его @Nik):

=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A5;ПОВТОР(B4;5);B4);ПОВТОР(B4;3);B4);ПОВТОР(B4;2);B4);ПОВТОР(B4;2);B4)

текст в A5, в B4 символ или символы, которые хотим сократить"Дело хозяйское, но имей ввиду:

1) формула моего знакомого @Nik не справляется со след. текстом:
г./Москва //Россия///////////////////////////////////////////////Московская обл.//

2) если все-таки нужен функционал отличный от СЖПРОБЕЛЫ, то более универсальным решением будет:
=ПОВТОР(B4;(ЛЕВСИМВ(A5)=B4))&ПОДСТАВИТЬ(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A5;" ";"|");B4;" "));" ";B4);"|";" ")&ПОВТОР(B4;(ПРАВСИМВ(A5)=B4))

;-)

или еще короче:

=ЛЕВСИМВ(A5)&ПОДСТАВИТЬ(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПСТР(A5;2;ДЛСТР(A5)-2);" ";"|");B4;" "));" ";B4);"|";" ")&ПРАВСИМВ(A5)

KL
[MVP - Microsoft Excel]

DaniilKВ продолжении темы, так сказать..
А реально ли из текста "тексто/вы?й\\те кст" с пом. формулы получить текст: "тексто_вы_й__те_кст" ?
пробовал по наивности формулу: =ПОДСТАВИТЬ(B2;{"\";" ";"/";"?";"*";"[";"]"};"_"), но она чего-то не то делает ..
:(

Такая формула возвращает массив из результатов замены для каждого из элементов массива второго параметра:

{"тексто/вы?й__те кст";"тексто/вы?й\\те_кст";"тексто_вы?й\\те кст";"тексто/вы_й\\те кст";"тексто/вы?й\\те кст";"тексто/вы?й\\те кст";"тексто/вы?й\\те кст"}

Думаю, что сделать это, используя только встроенные функции, либо невозможно либо нецелесообразно. Лучше писать пользовательскую функцию с "regular expressions" в VBA

Пардон, не обратил внимания на кол-во элементов в массиве:

=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ($A$1;"]";"_");"[";"_");"*";"_");"?";"_");"/";"_");" ";"_");"\";"_")

В 2003-й версии это как раз предел, в 2007-й можно добавлять 64 уровней

KL
[MVP - Microsoft Excel]