cbxLogin.Items.AddObject(Users.FieldByName('NAME').AsString, Pointer(ID));

Type

 TWrapper<T> = Class

  Strict Private

   FValue    : T;
   FTypeInfo : PTypeInfo;

   {$REGION ' Accessors '}

    Procedure SetValue(Const AValue : T);
    Function GetValue : T;

   {$ENDREGION}

  Public

   Constructor Create(Const AValue : T);

   Class Operator Implicit(Const AValue : T) : TWrapper<T>;
   Class Operator Implicit(Const AWrapper : TWrapper<T>) : T;

   Property Value : T Read GetValue Write SetValue;

 End;

{ TWrapper<T> }

//
Procedure TWrapper<T>.SetValue(Const AValue : T);
Begin

 FValue    := AValue;
 FTypeInfo := TypeInfo(T);

End;
//

//
Function TWrapper<T>.GetValue : T;
Begin

 If TypeInfo(T) <> FTypeInfo Then
  Raise Exception.CreateFmt('Invalid type casting. Expected: %s, actual: %s', [PTypeInfo(TypeInfo(T)).NameFld.ToString, FTypeInfo.NameFld.ToString]);

 Result := FValue;

End;
//

//
Constructor TWrapper<T>.Create(Const AValue : T);
Begin

 Inherited Create;

 Value := AValue;

End;
//

//
Class Operator TWrapper<T>.Implicit(Const AValue : T) : TWrapper<T>;
Begin

 Result := TWrapper<T>.Create(AValue);

End;
//

//
Class Operator TWrapper<T>.Implicit(Const AWrapper : TWrapper<T>) : T;
Begin

 Result := AWrapper.Value;

End;
//

Var

 List : TStringList;
 ID   : Integer;

begin

 List := TStringList.Create;
 ID   := 1024;

 List.AddObject('name', TWrapper<Integer>(ID));
 ID := TWrapper<Integer>(List.Objects[0]);

end.

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

Uses

 System.SysUtils, Generics.Collections, System.TypInfo, System.Classes;

Type

 TWrapper<T> = Class

  Strict Private

   Class Var

    FCache : TDictionary<T, TObject>;

   Class Constructor Initialize;
   Class Destructor Finalize;

  Strict Private

   FValue    : T;
   FTypeInfo : PTypeInfo;

   {$REGION ' Accessors '}

    Procedure SetValue(Const AValue : T);
    Function GetValue : T;

   {$ENDREGION}

  Public

   Constructor Create(Const AValue : T);

   Class Operator Implicit(Const AValue : T) : TWrapper<T>;
   Class Operator Implicit(Const AWrapper : TWrapper<T>) : T;

   Function __ObjRelease : Integer; Override;

   Property Value : T Read GetValue Write SetValue;

 End;

{ TWrapper<T> }

//
Class Constructor TWrapper<T>.Initialize;
Begin

 FCache := TDictionary<T, TObject>.Create;

End;
//

//
Class Destructor TWrapper<T>.Finalize;
Begin

 FCache.Free;

End;
//

//
Procedure TWrapper<T>.SetValue(Const AValue : T);
Begin

 FValue    := AValue;
 FTypeInfo := TypeInfo(T);

End;
//

//
Function TWrapper<T>.GetValue : T;
Begin

 If TypeInfo(T) <> FTypeInfo Then
  Raise Exception.CreateFmt('Invalid type casting. Expected: %s, actual: %s', [PTypeInfo(TypeInfo(T)).NameFld.ToString, FTypeInfo.NameFld.ToString]);

 Result := FValue;

End;
//

//
Constructor TWrapper<T>.Create(Const AValue : T);
Begin

 Inherited Create;

 Value := AValue;

End;
//

//
Class Operator TWrapper<T>.Implicit(Const AValue : T) : TWrapper<T>;
Begin

 TMonitor.Enter(FCache);
 Try

  If Not FCache.TryGetValue(AValue, TObject(Result)) Then
   Begin

    Result := TWrapper<T>.Create(AValue);

    FCache.Add(AValue, Result);

   End;

 Finally

  TMonitor.Exit(FCache);

 End;

End;
//

//
Class Operator TWrapper<T>.Implicit(Const AWrapper : TWrapper<T>) : T;
Begin

 Result := AWrapper.Value;

End;
//

//
Function TWrapper<T>.__ObjRelease : Integer;
Begin

 Result := Inherited __ObjRelease;

 If Result = 1 Then
  Begin

   TMonitor.Enter(FCache);
   Try

    FCache.Remove(FValue);

   Finally

    TMonitor.Exit(FCache);

   End;

  End;

End;
//

Var

 [weak]
 w  : TWrapper<Integer>; // for test of releasing

Procedure Test;
Var

 sl : TStringList;
 index : Integer;

Begin

 sl := TStringList.Create;

 w := TWrapper<Integer>(1);
 WriteLn('addr of w: ', NativeUInt(Pointer(w)));

 sl.AddObject('one', w);
 sl.AddObject('two', TWrapper<Integer>(2));
 sl.AddObject('three', TWrapper<Integer>(3));
 sl.AddObject('four', TWrapper<Integer>(4));
 sl.AddObject('five', TWrapper<Integer>(1));

 For Index := 0 To sl.Count - 1 Do
  WriteLn(sl[Index], ' = ', TWrapper<Integer>(sl.Objects[Index]).Value, ' (', NativeUInt(Pointer(sl.Objects[Index])), ')');

End;

Begin

 Test;

 WriteLn('addr of w: ', NativeUInt(Pointer(w)));

End.

addr of w: 24513104
one = 1 (24513104)
two = 2 (24512944)
three = 3 (24512784)
four = 4 (24509344)
five = 1 (24513104)
addr of w: 0