Вот методом "пожмакав" - нашел следующее -
OnCurrent отрабатвает на всякое переключение как его последний элемент -и, в свойстве формы CurrentView показывает текущий установленный режим.
Жмакал в OfficeXP
Удачи,
Виктоша

[Лох Позорный ]
>В принципе, проверка CurrentView на событии Current должна работать. Но >только если есть хотя бы одна запись. Иначе Current не случится.

Жмакнеш F1 - получишь: The Current event occurs when the focus moves to a record, making it the current record, or when the form is refreshed or requeried

В данном случае - the form is refreshed or requeried - работает ВСЕГДА, независимо от "привязанности" формы к источнику. ПРОСТО ПОПРОБУЙ

Удачи, Виктоша

To [Serge Gavrilov ]

> Ну как может возникнуть Current, если нет записей?
>Сами-то пробовали?

A) Сами пробовали
Б) The Current event occurs when the focus moves to a record, making it the current record, or when the form is refreshed or requeried
В данном случае - the form is refreshed or requeried - работает ВСЕГДА, независимо от "привязанности" формы к источнику. ПРОСТО ПОПРОБУЙ

Удачи,
Виктоша

To [Serge Gavrilov ], [Лох Позорный]
Уели, - мол и к источнику привязан и записей в нем нет, так еще и добавление запрещено - НУ, НЕ РАБОТАЕТ current тогда - ПРОСТИТЕ ДЯДЕНЬКИ...
Я даже спрашивать не буду для кого такая комбинация...

Но таймер-то все равно работает...

Привет
Виктоша

To [Лох Позорный]
> Таймер работает
>Только случается он еще чаще чем Current
>И уж совсем никак не привязан к смене режимов

случается как закажешь, а что не привязан - так и хорошо, - на это пальчики есть. Главное случается РЕГУЛЯРНО.

Виктоша

To [Лох Позорный ]
Про пальчики и название топика

1. добавляешь в проект модуль класса, например clsFormMode следующего содержания:
-----------------
Option Explicit
Private currentMode As Long 'текущий режим
Private prevMode As Long 'предыдущий режим

Event ViewModeChanged(prevMode As Long, currentMode As Long)

Property Let setViewMode(tMode As Long)
If currentMode <> tMode Then
prevMode = currentMode
currentMode = tMode
'испускаем событие об изменении режима просмотра
RaiseEvent ViewModeChanged(prevMode, currentMode)
End If
End Property

Private Sub Class_Initialize()
currentMode = -1 ' тут по желанию - (-1) для желающих отловить загрузку
prevMode = -1
End Sub

-----------------

2. Далее в модуле любимой формы
2.а) объявляешь прерменную
Private WithEvents myModeRaiser As clsFormMode

2.б) оформляешь OnTimer:
Private Sub Form_Timer()
myModeRaiser.setViewMode = Me.CurrentView
End Sub

2.в) подписываешься на события любимого класса
Private Sub myModeRaiser_ViewModeChanged(prevMode As Long, currentMode As Long)
'ЭТО МЕСТО ОТЛОВА
'Тут любимые действия при смене режима
MsgBox "Было:" & CStr(prevMode) & " Стало:" & CStr(currentMode)
End Sub

2.с) Не забыть выставить частоту TimerInterval в любимое значение
------------------------------------------------------
3) Можно оправиться и покурить.

С Приветом,
Виктоша

To [Лох Позорный ]

Да, в 97м ЭТО (RaiseEvent) не сработает.

To [Geo]
В обчем, на сабклассинг потихонечку...

[тут почикано....]
>Таймер - неплохо, но прежде, чем он заметит переключение режима,
> пользователь может успеть на что-то нажать, и изменения записи либо не
> произойдут, когда нужно, либо наоборот.

Это от частоты зависит

> Модуль класса - на этапе разработки, во всяком случае, очень плохо.
> Любая неотловленная ошибка - он от формы "отваливается", а иногда после > нескольких раз глючит сам акцесс

Ошибки - отдельно, глючит - отдельно...

Ну да - в тех трех притопах, что я изобрАзить пытался не хватает инициализации и освобождения...

Из заявленных требований следует примерно вот что -
A) либо городить огород с состояниями формы (через клиентский класс) городить - это пробовать надо и вряд ли читаемо в итоге будет. Типа нет записей - включаем таймер, обнаружились - отключаем и ждем Текущую...

Б) Создать и подвязать к форме самодельное popup - меню c нужными кнопками,
если недостаточно, то еще и обычное меню,
обвязать все это классом а-ля см ранее, с нужным к-вом
Private WithEvents tControl as Office.CommandButton ... etc
После чего ловить Click от tControl и распоряжаться им по своему усмотрению



Может кто чего лучше предложит?

С уважением ко Всем,
Виктоша

Тема, как будто, закрыта, потому заранее извиняюсь сразу перед всеми.
Из того класса (выше по флейму) , пока получилась вот такая штука:

Модуль класса (clsFormMode)
Option Compare Database
Option Explicit

Private Const CSEP As String = "[Event Procedure]"
Private Const CDEFTIMERINT As Long = 300 '

Private currentMode As Long '
Private prevMode As Long '

Private WithEvents tForm As Form ' форма, за которой следим

Private sourceTimerInt As Long ' исходный интервал таймера в форме


Event ViewModeChanged(prevMode As Long, currentMode As Long)

Sub Init(uForm As Form)
On Error Resume Next
Set tForm = uForm
With tForm
'Подписка на события формы
sourceTimerInt = .TimerInterval .OnCurrent = CSEP
.OnApplyFilter = CSEP

'считываем стартовый режим
setViewMode = .CurrentView '
End With
SetTimer 'Просто установим таймер - ,ближайший Current его выключит
End Sub

Private Sub SetTimer()
' включает "свой" таймер
On Error Resume Next
If sourceTimerInt = 0 Or sourceTimerInt > CDEFTIMERINT Then
tForm.TimerInterval = CDEFTIMERINT
End If
tForm.OnTimer = CSEP
End Sub

Private Sub ClearTimer()
'Отписываемся от таймера
On Error Resume Next
With tForm
.OnTimer = vbNullString
.TimerInterval = sourceTimerInt '
End With
End Sub

Private Property Let setViewMode(tMode As Long)
'
If currentMode <> tMode Then
prevMode = currentMode
currentMode = tMode
RaiseEvent ViewModeChanged(prevMode, currentMode)
End If
End Property

Private Sub Class_Initialize()
currentMode = -1
prevMode = -1
End Sub

Private Sub Class_Terminate()
Call Terminate
End Sub

Private Sub tForm_ApplyFilter(Cancel As Integer, ApplyType As Integer)
'события происходит до фактической смены источника,
' не знаем, будут ли записи - включаем таймер
SetTimer
End Sub

Private Sub tForm_Current()
'если сюда попали - таймер точно не нужен
ClearTimer
setViewMode = tForm.CurrentView
End Sub

Private Sub tForm_Timer()
' здесь оказываемся только при пустом источнике
setViewMode = tForm.CurrentView
End Sub

Private Sub Terminate()
'финальная очистка
ClearTimer
Set tForm = Nothing
End Sub
'--------------------------------------------------
Далее в форме:
Private WithEvents oV As clsFormMode

Private Sub Form_Close()
Set oV = Nothing
End Sub

Private Sub Form_Load()
Set oV = New clsFormMode
oV.Init Me
End Sub

Private Sub oV_ViewModeChanged(prevMode As Long, currentMode As Long)
MsgBox "Было: " & CStr(prevMode) & " Стало:" & CStr(currentMode)
End Sub
'------------------------------------------
Плюсы - работает, и выглядит не настолько уродливо, как мне поначалу казалось.
Минусы - переопределяет таймер, тем самым создает проблему протокола его совместного использования, если форма (или другой управляющий ею класс ) сама подписана на таймер. Например, если форма "по таймеру" желает посылать почтовый привет администратору, - может получиться не здорово сразу для всех.

Виктоша.

To [Лох Позорный]

>Если форма сама обрабатывает это событие - то сначала вызовется
>обработчик твоего класса, потом обработчик формы.
>Проверять лениво, но вроде должно быть так.

Так и будет.
В этом и проблема.
В общем случае это не только проблема таймера, но с ним она "яснее".
Таймер выделяется среди прочих событий своей "чужеродностью". По отношению к прочим событиям слушатели пассивны. От них (Слушателей) не зависит - произойдут ожидаемые события или нет. По отношению к таким событиям слушатели изначально равноправны и должны делиться чем и как умеют.

Таймер - по существу ресурс (в данном случае совместно используемый). По отношению к таймеру - МОЖНО ЗАДАВАТЬ ТЕМП. Это значит, что он МОЖЕТ нести в себе ЗАДАЧНЫЕ активности типа "Прочитать" файлик с ftp, опубликовать что-либо в web, статус формы почитать и т.д. - Всякие РЕГЛАМЕНТНЫЕ действия навесить, происходящие по расписанию. Алгоритмические активности, если есть такое слово.
Но, поскольку, физически в каждый данный момент ОН (таймер) один (если не лезть в WIN API), то возникает тема ПРОТОКОЛА СОВМЕСТНОГО ИСПОЛЬЗОВАНИЯ ОБЩЕГО ресурса. В принципе "пару строчек" поменять в том коде, НО. Тогда возникает Таймер С Договором О Правилах Его Использования.
По причине потенциального наличия множества РЕГЛАМЕНТОВ, требующих
СВОЕГО темпа течения времени.

Пока шибко некогда, но, кажется, что к кнопкам привязаться и правильнее и красившЕЕ во ВСЕХ отношениях. Может выберу ...

Виктоша

ЗЫ
Пардону за многословие...

To [Senin Viktor]

Вообще-то это уже чуть другая тема, да и в таймерах я не силен. Но.
Не вполне я уверен в правоте собственных утверждений вообще, даже по отношению к Access, поскольку все это умственно. А про таймеры в частности - я имел в виду NT-евые waitable timers. Сходу не видно, почему их не может быть больше одного.

Может быть это еще кому-то интересно...

1) Ставим ссылку на библиотеку Office

2) Создаем форму
Модуль класса формы:
Option Compare Database
Option Explicit

'кнопка перейти к виду формы
Private WithEvents toFormVBtn As Office.CommandBarButton
'кнопка перйти к виду таблицы
Private WithEvents toTblVBtn As Office.CommandBarButton


Private Sub findButtons()
'процедура привязки к стандартым кнопкам смена вида формы
'идентификаторы взяты для officeXP
'для 2000 идентификаторы не проверял
Set toFormVBtn = CommandBars.FindControl(Id:=502)
Set toTblVBtn = CommandBars.FindControl(Id:=498)
End Sub

Private Sub ClearButtons()
'отвязка от кнопок
Set toFormVBtn = Nothing
Set toTblVBtn = Nothing
End Sub

Private Sub Form_Close()
'при закрытии формы отвяжем кнопки
Call ClearButtons
End Sub

Private Sub Form_Load()
'при загрузке формы подвяжем кнопки.
Call findButtons
End Sub

Private Sub toFormVBtn_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
'Собственно перехват нажатия кнопки прехода к виду формы
MsgBox "Нажата кнопка - Прейти к виду формы"
End Sub

Private Sub toTblVBtn_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
'аналогично для кгопки "перейти к табличному виду"
MsgBox "Нажата кнопка - перейти к виду таблицы"
End Sub

3) Вот, собственно, и все.
-------------------------------------------------
Обсуждение
А) Мне это нравится гораздо больше чем все предыдущее.

Б) Полной уверенности в надежности все-таки нет. См. замечания Geo по поводу "отваливающихся" переменных класса. В моей практике наблюдалась специфическая подкрутка этой проблемы, связанная с потерей указателей на свойства и методы OLE-объекта при подъеме приложения из свопа.
Будут ли замечания или комментиарии?

С Уважением,

Виктоша

To [Лох Позорный], [Geo] Ok
Спасибо, Пардону за назойливость... -)

Поначалу на замечания возникла такая реакция - скомбинировать 1) и 2)

Однако ( почесав в затылке) предложение 2) (с подвязанными кнопками) (почти) снимается (то есть совсем сырец...). Хотя мне оно определенно нравится возможностью отменить нажатие кнопки, что вносит доп. уровень управления.
Доп. причина для снятия - возможно, кнопок должно быть больше - надо на контекстных меню еще поискать по вложенным формам...

предложение с тем, что было названо clsFormMode во первых, покрывает заказанные потребности не требуя динамических связей с доп. библиотеками, и, в этом смысле, оно "круче". И, хотя подвязка к таймеру, на мой взгляд, не вполне эстетична, все-таки приемлема, с учетом вариантов обхода проблем (если они - проблемы - есть в конкретном случае).
Про обходы - второй вариант - б) слушать таймер ДРУГОЙ формы - это совсем просто.


Рассказ о том, что что-то в Dirty проверяется значит только одно - реальные потребности существенно уже "спектра возможностей". Это больше похоже не на отлов переключений, а косвенное выполнение действий скрытых в режиме таблицы кнопок.

Для меня любобытно вот что - я не первый день, как будто, в клавиши тюкаю, а вот не возникало у меня потребности - видимо, в консерватории что-то править надо.
Для начала научиться морды в топики вставлять. -)
С Уважением,
Виктоша