* процедурное программирование
tt =  10 
? tt
tt =  20 
? tt

* ООП
мойбубен = newobject('pp')
мойбубен.ff =  10 
мойбубен.ff =  20 
define class pp AS custom
	ff = null
	procedure ff_assign
		lparameters tnValue
		THIS.ff = tnValue
		? tnValue
	endproc
enddefine 

lparameters tcSql_updateTableName, 	;  	&& таблица на сервере	
			tcCADkeyFieldList, 		;	&& ключь-линк в таблице
			tcCADupdatableFieldList,;	&& обновляемые поля в таблице  (список через запятую)
			tcCADcursorSchema, 		;	&& схема - преобразов-е типов  (список через зяпятую)
			tcWhere, 				;	&& условие в запросе (выражение после WHERE)
			tcSelectedFieldsList,   ;	&& поля в строке запроса (необяз-й параметр)
			tcGroupBy,				;	&& строка - список через запятую
			tcOrderBy,				;	&& строка - список через запятую
			tcSelectCmdADD,			;	&& добавчик к SelectCmd
			tcSelectCmd,			;	&& если уж совсем нестандартный запрос, то передаем сюда уже готовый запрос
			tcTimeStampFieldsList       && список полей TimeStamp

with this
	if !.llocktransactions and !.CheckConnection()
		return .f.
	endif

	.Tables         	= tcSql_updateTableName
	.keyFieldList		= tcCADkeyFieldList
	* начитываем если необходимо список полей в таблице на Sql сервере
	.CheckUpdatableFieldList(@tcCADupdatableFieldList, tcSelectedFieldsList, tcTimeStampFieldsList)
	.UpdatableFieldList = upper(strtran(strtran(tcCADupdatableFieldList, "[", ""), "]", "")) && строка в виде 'Fld1, Fld2'
	.sendUpdates = !empty(.UpdatableFieldList)
	
	* номер соединения
	.DataSource = cast(.nConnection as integer)
	
	* формируем запрос для КАДа
	if !empty(tcSelectCmd) and vartype(tcSelectCmd)="C"
		.cSelectCmd_const = tcSelectCmd
	else
		text to .cSelectCmd_const noshow textmerge pretext  15  
			select
				<<iif(empty(tcSelectedFieldsList), tcCADkeyFieldList+","+tcCADupdatableFieldList, tcSelectedFieldsList)>>
				from <<tcSql_updateTableName>>
		endtext
	endif
	
	text to .cSelectCmd_ADD noshow textmerge pretext  15  
		<<iif(!empty(tcGroupBy), "GROUP BY "+tcGroupBy, "")>>
		<<iif(!empty(tcOrderBy), "ORDER BY "+tcOrderBy, "")>>
		<<iif(!empty(tcSelectCmdADD), tcSelectCmdADD, "")>>
	endtext	
	.cWhere	  = tcWhere && складываем все в строку
	
	if !empty(tcCADcursorSchema) and .checkcursorschema(@tcCADcursorSchema)
		.cursorsChema 	= tcCADcursorSchema   && строка в виде 'Fld c(16)'
	else
		if !empty(tcCADcursorSchema)		
			return .f. 
		endif
	endif
	.UseCursorSchema = !empty(.cursorschema)
		
	local laFieldsArr( 1 ), lnField, lcField 
	* формируем строку для апдейта
	.updateNameList 	=  iif( !empty(tcCADkeyFieldList), ;
								tcCADkeyFieldList + ' ' + .Tables+'.'+tcCADkeyFieldList, ;
								"")
	for lnField= 1  to alines(laFieldsArr,tcCADupdatableFieldList,',')
		lcField = alltrim(laFieldsArr(lnField))
		if !empty(lcField)
			.updateNameList = .updateNameList +iif(!empty(.updateNameList),', ','') + ;
							  strtran(strtran(lcField, "[", ""), "]", "") + ' ' + .Tables+'.'+lcField
		endif
	endfor
	
	* нужно наверное присвоить если действительно есть в селекткмд
	*!*		if !empty(tcTimeStampFieldsList)
	*!*			.TimestampFieldList = tcTimeStampFieldsList
	*!*		endif

endwith
return .t.