ReSQL.ru
     
powered by simpleCommunicator - 2.0.37     © 2025 Programmizd 02
Мобильная версия    Контакт    Правила    FAQ    Помощь
Доб. в избранное | Игнор. тему | Прикреп. тему | Пометить прочит. / непрочит. | Фильтр
Форумы / Caché, Ensemble, DeepSee, MiniM, IRIS, GT.M [игнор отключен] [закрыт для гостей] / Почему так сортируются строки?
29 сообщений из 29, показаны все 2 страниц
  все  
Почему так сортируются строки?
    #39128410
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Коллеги, буду благодарен, если кто-то сможет поделиться соображениями по данному поводу.

Дано: Cache 2012.2.5 - 2015.1.2.

Локаль: ^%SYS("LOCALE","CURRENT")="ruw8"
Таблица сортировки: Cyrillic2 или Cache standard (не важно).

Вопрос: Есть ли разумное объяснение такой сортировке? kill b
 set a=1E30,b(+a)=1,b(+a_"1")=3,b(+a_"1a")="3a"
 set a=3E30,b(+a)=2,b(+a_"1")=4,b(+a_"1a")="4a"
 set b($c(2))="??"
 zwrite b

Код: plaintext
1.
2.
3.
4.
5.
6.
b(1000000000000000000000000000000)=1
b(3000000000000000000000000000000)=2
b("10000000000000000000000000000001")=3
b("30000000000000000000000000000001")=4
b($c(2))="??"
b("10000000000000000000000000000001a")="3a"
b("30000000000000000000000000000001a")="4a"

При этом стандартная проверка локали: kill b for i=0:1:127 s b($c(i))=iпроходит нормально: сначала числа, потом строки в порядке возрастания кодов ASCII.
...
Рейтинг: 0 / 0
15.12.2015, 13:06
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128431
Фотография DAiMor
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
DAiMor
Участник
Alexey Maslov
Код: plaintext
1.
b("10000000000000000000000000000001")=3
b("30000000000000000000000000000001")=4

очевидно, что эти узлы сортируются как числовые, несмотря на то что отображаются как строки
когда они точно становятся строками, тогда уже точно сортируются нормально

но это уже вопрос к IS, корректно ли что строки которые только с числами сортируются как числа, а не как строки

у меня так же сортируется
Cache for Windows (x86-64) 2016.1 (Build 596U) Mon Nov 9 2015 21:12:55 EST
...
Рейтинг: 0 / 0
15.12.2015, 13:17
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128467
Фотография ну я
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
ну я
Участник
Alexey Maslov,
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
USER>kill b
 
USER>set b(+a_"1")=3,b(+a_"1a")="3a"
 
USER>set b(+a_"1")=4,b(+a_"1a")="4a"
 
USER>set b($c(2))="??"
 
USER>zwrite b
b("30000000000000000000000000000001")=4
b($c(2))="??"
b("30000000000000000000000000000001a")="4a"
 
USER>w $zv
Cache for Windows (x86-64) 2008.2 (Build 506) Thu Sep 4 2008 11:07:26 EDT

У меня с записями маркированными как 3 и 3а что-то куда-то вообще уехало...
...
Рейтинг: 0 / 0
15.12.2015, 13:31
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128469
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
DAiMor,
Вот и мне так показалось. Кстати, результат такой же, даже если подобное "псевдочисло" вызывает числовое переполнение, например: USER>s j=310,n=$tr($j("",j)," ",1) set b(n)=j zw b
b(1000000000000000000000000000000)=1
b(3000000000000000000000000000000)=2
b("10000000000000000000000000000001")=3
b("30000000000000000000000000000001")=4
b("11111111111111111111111111111111111111...111")=310
b($c(2))="c2"
b("10000000000000000000000000000001a")="3a"
b("30000000000000000000000000000001a")="4a"

USER>w n=+n

W n=+n
^
<MAXNUMBER>
...
Рейтинг: 0 / 0
15.12.2015, 13:31
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128470
Фотография ну я
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
ну я
Участник
сорри, только заметил что в тесте не менял a
...
Рейтинг: 0 / 0
15.12.2015, 13:32
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128477
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
ну я,

"а что нам скажет товарищ MiniM"?

Проще выполнять однострочник:k b s a=1E30,b(+a)=1,b(+a_"1")=3,b(+a_"1a")="3a",a=3E30,b(+a)=2,b(+a_"1")=4,b(+a_"1a")="4a",b($c(2))="c2" zwrite b
...
Рейтинг: 0 / 0
15.12.2015, 13:36
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128502
Фотография ну я
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
ну я
Участник
Код: plaintext
1.
2.
3.
4.
5.
6.
b(1E+30)=1
b(3E+30)=2
b("&#9787;")="c2"
b("1E+301")=3
b("1E+301a")="3a"
b("3E+301")=4
b("3E+301a")="4a"
...
Рейтинг: 0 / 0
15.12.2015, 13:47
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128505
Фотография ну я
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
ну я
Участник
b("&#9787;")="c2"Тут в индексе в досовой кодировке рожица должна быть.
...
Рейтинг: 0 / 0
15.12.2015, 13:49
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128522
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
ну я,

спасибо, в MiniM сортируется, как и ожидается, хотя, похоже, есть (другая) ошибка. Согласно Стандарту, унарный плюс (как и любая арифметическая операция) должен привести число к каноническому виду, e.g.
Код: plaintext
1.
2.
USER>set a="1E30" write +a,!,+a_"1"
1000000000000000000000000000000
10000000000000000000000000000001
...
Рейтинг: 0 / 0
15.12.2015, 13:58
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128526
Александр Коблов
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Александр Коблов
Участник
Это наверное не объяснение, но в документации есть абзац про порядок сортировки чисел и строк: Numeric and String-Valued Subscripts

Обратите внимание, что порядок сортировки строк не обязательно совпадает с порядком кодов символов:

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
USER>set ^a("текст")=1
 
USER>set ^a("ТЕКСТ")=1

USER>write ##class(%Collate).LogicalToDisplay(##class(%GlobalEdit).Open("a").Collation)
Cyrillic2

USER>zwrite ^a
^a("текст")=1
^a("ТЕКСТ")=1
 
USER>write $Ascii("т")
242
USER>write $Ascii("Т")
210
...
Рейтинг: 0 / 0
15.12.2015, 14:01
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128560
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Александр Коблов,

спасибо, об этом знаем :) не случайно ведь привёл: При этом стандартная проверка локали:
kill b for i=0:1:127 s b($c(i))=i 
проходит нормально: сначала числа, потом строки в порядке возрастания кодов ASCII.К тому же в пределах первой половины таблицы ASCII никаких чудес быть не должно (согласно Стандарту языка ISO/M).

В качестве попытки объяснения можно было бы привести результат выполнения $isvalidnum, однако: set j=310,n=$tr($j("",j)," ",1)
 for i="10000000000000000000000000000001","30000000000000000000000000000001",n { 
  w $isvalidnum(i)_" $length(i)="_$l(i)_" i="_i,! ;_" i=+i:"_(i=+i),!
}

Код: plaintext
1.
2.
1 $length(i)=32 i=10000000000000000000000000000001
1 $length(i)=32 i=30000000000000000000000000000001
0 $length(i)=310 i=111...111111111111111111111111111111
при этом n, как было показано ранее, тоже сортируется в индексе как число.
...
Рейтинг: 0 / 0
15.12.2015, 14:16
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128685
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Коллеги,
понимаю, что, наверное, уже надоел, и, конечно, обращусь в WRC, но может кто-нибудь для статистики выполнить пресловутый однострочник в MSM?
Я почти уверен в результате, но всё же... k b s a=1E30,b(+a)=1,b(+a_"1")=3,b(+a_"1a")="3a",a=3E30,b(+a)=2,b(+a_"1")=4,b(+a_"1a")="4a",b($c(2))="c2" zwrite b
...
Рейтинг: 0 / 0
15.12.2015, 15:38
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128690
Фотография ну я
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
ну я
Участник
Alexey Maslov,

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
MSM for Windows NT, Version 4.4.1 (RC-1)  Line #1  UCI: ******* Job #3
>k b s a=1E30,b(+a)=1,b(+a_"1")=3,b(+a_"1a")="3a",a=3E30,b(+a)=2,b(+a_"1")=4,b(+a_"1a")="4a",b($c(2))="c2" zwrite b
b(1000000000000000000000000000000)=1
b(3000000000000000000000000000000)=2
b("")="c2"
b("10000000000000000000000000000001")=3
b("10000000000000000000000000000001a")="3a"
b("30000000000000000000000000000001")=4
b("30000000000000000000000000000001a")="4a"
...
Рейтинг: 0 / 0
15.12.2015, 15:41
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128699
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Уже подзабыл, дружит ли MSM с управляющими в индексах, если нет, то последнее присваивание (b($c(2))="c2") можно смело выкинуть, т.к. $c(2) в Cache сортируется правильно и не влияет на суть примера.
...
Рейтинг: 0 / 0
15.12.2015, 15:44
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128710
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
ну я, ещё раз спасибо.

Похоже, у основных "M-соседей" сортируется правильно, бяка только в Cache. Не имею доступа к экзотике типа M21 и MumpsV1, но это уже не столь важно.
...
Рейтинг: 0 / 0
15.12.2015, 15:49
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128731
Valeriu
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Valeriu
Участник
Alexey Maslov,

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
GTM>k b s a=1E30,b(+a)=1,b(+a_"1")=3,b(+a_"1a")="3a",a=3E30,b(+a)=2,b(+a_"1")=4,b(+a_"1a")="4a",b($c(2))="c2" zwrite b
b(1000000000000000000000000000000)=1
b(3000000000000000000000000000000)=2
b($C(2))="c2"
b("10000000000000000000000000000001")=3
b("10000000000000000000000000000001a")="3a"
b("30000000000000000000000000000001")=4
b("30000000000000000000000000000001a")="4a"

GTM>
...
Рейтинг: 0 / 0
15.12.2015, 16:01
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128823
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Valeriu,

спасибо.
...
Рейтинг: 0 / 0
15.12.2015, 16:44
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128869
servit
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
servit
Участник
Alexey MaslovВопрос: Есть ли разумное объяснение такой сортировке?Пока всё согласно документации:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
k b
s b(12345678901234567891)=1
s b("12345678901234567891")=2
s b("11345678901234567891")=3
zw b
w !
k b
s b(012345678901234567891)=1
s b("012345678901234567891")=2
s b("011345678901234567891")=3
zw b

b("11345678901234567891")=3
b(12345678901234567890)=1
b("12345678901234567891")=2
 
b(12345678901234567890)=1
b("011345678901234567891")=3
b("012345678901234567891")=2
Именно поэтому "1111111111111111...11111111111111111" сортируется как число, а не строка, хотя это строка.
Но достаточно жёстко указать Caché воспринимать её как строку, как она уже сортируется как строка, например:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
s b($c(0))=$c(0)
s j=110,b($tr($j("",j)," ",1))=j
s j=110,b($tr($j("",j)," ","0"))=j
zw b

b("11111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111")=110
b($c(0))=$c(0)
b("00000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000")=110

s b($c(0))=$c(0)
s j=110,b("0"_$tr($j("",j-1)," ",1))=j ; указываем явно строчную сортировку
s j=110,b($tr($j("",j)," ","0"))=j
zw b

b($c(0))=$c(0)
b("00000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000")=110
b("01111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111111")=110
...
Рейтинг: 0 / 0
15.12.2015, 17:10
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39128942
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
servit,

у вас другой код, и другие результаты. Свой пример я ещё немного доработал:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
k b s a=1E30,b(+a)=1,b(+a_"11")=11,b(+a_"111")=111,b(+a_"1a")="3a",a=3E30,b(+a)=3,b(+a_"33")=33,b(+a_"333")=333,b(+a_"1a")="4a" zwrite b
b(1000000000000000000000000000000)=1
b(3000000000000000000000000000000)=3
b("100000000000000000000000000000011")=11
b("300000000000000000000000000000033")=33
b("1000000000000000000000000000000111")=111
b("3000000000000000000000000000000333")=333
b("10000000000000000000000000000001a")="3a"
b("30000000000000000000000000000001a")="4a"
Видите, что получается? По документации должно быть 2 интервала сортировки:
1) числа - сортируются как числа
2) не числа - сортируются алфавитно.

А мы видим три:
1) числа - сортируются как числа (1-3)
1*) "псевдочисла" - сортируются как числа (11-333)
2) не числа - сортируются алфавитно (3a-4a).

(Временно) прекращаю обсуждение, т.к. открыл проблему в WRC. Если ISC не будет возражать, отпишусь о результатах.
...
Рейтинг: 0 / 0
15.12.2015, 18:04
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39129003
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
servit,

напоследок приведу модифицированный пример без комментариев.
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
w ! k b set j=310,n=$tr($j("",j)," ",1),b(n)="Over1",n=$tr($j("",j)," ",2),b(n)="Over2",n=$tr($j("",j+1)," ",1),b(n)="Over11" s a=1E30,b(+a)=1,b(+a_"11")=11,b(+a_"111")=111,b(+a_"1a")="3a",a=3E30,b(+a)=3,b(+a_"33")=33,b(+a_"333")=333,b(+a_"1a")="4a" s x="" f { s x=$o(b(x)) q:x=""  w $j(b(x),10),"  isvalidnum? ",$isvalidnum(x) try {w "  x=+x? ",x=+x,"  x-1+1=x? ",x-1+1=x,!} catch { w $ze,! }}

         1  isvalidnum? 1  x=+x? 1  x-1+1=x? 1
         3  isvalidnum? 1  x=+x? 1  x-1+1=x? 1
        11  isvalidnum? 1  x=+x? 0  x-1+1=x? 0
        33  isvalidnum? 1  x=+x? 0  x-1+1=x? 0
       111  isvalidnum? 1  x=+x? 0  x-1+1=x? 0
       333  isvalidnum? 1  x=+x? 0  x-1+1=x? 0
     Over1  isvalidnum? 0  x=+x? <MAXNUMBER>
     Over2  isvalidnum? 0  x=+x? <MAXNUMBER>
    Over11  isvalidnum? 0  x=+x? <MAXNUMBER>
        3a  isvalidnum? 0  x=+x? 0  x-1+1=x? 0
        4a  isvalidnum? 0  x=+x? 0  x-1+1=x? 0
...
Рейтинг: 0 / 0
15.12.2015, 18:36
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39129199
eduard93
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
eduard93
Участник
Alexey Maslov, у вас числа больше максимально возможного целого числа в Cache 2^63-1 = 9223372036854775807.
...
Рейтинг: 0 / 0
15.12.2015, 21:51
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39129330
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
eduard93, правильно. Тогда вопрос, почему Cache считает их числами:
Код: plaintext
1.
2.
3.
PERF>w $isvalidnum(9223372036854775808)
1
PERF>w $isvalidnum(19223372036854775808)
1
если произошёл выход за рамки диапазона чисел?
...
Рейтинг: 0 / 0
16.12.2015, 08:05
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39129337
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Возможно, дело в этом: Cache ObjectScript Reference
$DOUBLENote:
A Cache numeric string literal that exceeds the min/max range supported by Cache floating point data types (for example, “1E128”) is automatically converted to an IEEE double-precision floating point number. This conversion is only performed on numeric literals; it is not performed on the results of mathematical operations. This automatic conversion can be controlled on a per-process basis using the TruncateOverflow() method of the %SYSTEM.Process class. The system-wide default behavior can be established by setting the TruncateOverflow property of the Config.Miscellaneous class.Это объясняет поведение $isvalidnum, но не оправдывает сортировку, которая должна подчиняться не внутренней функции, а Стандарту, который в этой важной части, как мы вчера увидели, неплохо соблюдается в других М-системах.
...
Рейтинг: 0 / 0
16.12.2015, 08:24
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39129614
Timur Safin
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Timur Safin
Участник
Alexey Maslov,

Какому такому стандарту? :)

(Он был про другой язык, он не активен, он сообществу не нужен и не поддерживается)
...
Рейтинг: 0 / 0
16.12.2015, 12:26
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39129658
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Timur Safin,

тем не менее, в документации немало ссылок на Стандарт ISO 11756-1999 (поиск работает :). Вот, например, в тему: RoutinesWhen you create routines in Cache, you can choose the programming language for each routine. The choices are as follows:
Cache ObjectScript, which is a superset of the ISO 11756-1999 standard M programming language. If you are an M programmer, you can run your existing M applications on Cache with no change.
Timur SafinОн был про другой язык, он не активен, он сообществу не нужен и не поддерживаетсяРасскажите об этом, например, участникам этого сборища , им полезно будет узнать, что они "скорее мертвы, чем живы".

Стоит ли объяснять, зачем нужна обратная совместимость со Стандартом, кстати, весьма хорошо обеспечиваемая в Cache? Случайно найденное мною исключение лишь подтверждает правило :)
...
Рейтинг: 0 / 0
16.12.2015, 13:01
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39131257
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
Замыкая круг.
Разработчик в принципе подтвердил моё рассуждение в 18564206 , только вот никаких псевдочисел нет: "In ANSI collation, any number (or string that is in canonic numeric form) is collated numerically, before all non-numeric strings."
Причём это не всегда было так, а начиная с какой-то версии (не сказали с какой, но видимо c довольно давней). Не важен ни результат $isvalidnum, ни возможный <MAXNUMBER> при "классической" проверке на число: n=+n.
Не стал бы и писать об этом, но механизм сортировки один из "ядерных", и его непонятное поведение меня встревожило. Теперь успокоили :)

Всем спасибо, кто поучаствовал.
...
Рейтинг: 0 / 0
17.12.2015, 19:52
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39131415
Timur Safin
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Timur Safin
Участник
Alexey Maslov"In ANSI collation, any number (or string that is in canonic numeric form) is collated numerically, before all non-numeric strings."
Причём это не всегда было так, а начиная с какой-то версии (не сказали с какой, но видимо c довольно давней).
Это с SPJ932 присутствующем в продукте еще с 1993(!) года.
...
Рейтинг: 0 / 0
17.12.2015, 23:41
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39253999
servit
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
servit
Участник
Alexey Maslov ,

Подробное объяснение
...
Рейтинг: 0 / 0
10.06.2016, 08:22
| Ответить | Цитировать | Написать  
Почему так сортируются строки?
    #39254255
Alexey Maslov
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey Maslov
Участник
servit,

спасибо, правда я и тогда всё понял :). Однако лучше бы для большей понятности автор поста употребил оператор ]], а не ], т.к. ] трактуется как "следует-за в порядке кодов символов без учёта специфики числовой сортировки". Для преодоления этого недостатка и был когда-то добавлен в язык Стандарта ISO/1995 оператор ]] - "следует-за в порядке действующей Collation". Мой старый пример, расширенный примером автора, наглядно показывает разницу:
Код: plaintext
1.
2.
3.
4.
num k b 
  s b("12345678901234567870")="Num20 @ S.Hobbs" s b("12345678901234567874")="NotNum20 @ S.Hobbs"
  s a=1E30,b(+a)=1,b(+a_"11")=11,b(+a_"111")=111,b(+a_"1a")="3a",a=3E30,b(+a)=3,b(+a_"33")=33,b(+a_"333")=333,b(+a_"1a")="4a"
  s i="",i0="" f  s i=$o(b(i)) q:i=""  w "(i]]i0)=",i]]i0," (i]i0)=",i]i0," (i>i0)=",i>i0,?30," " zw b(i) s i0=i
  q
 
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
LEARN>d num^ztest
(i]]i0)=1 (i]i0)=1 (i>i0)=1    b(12345678901234567870)="Num20 @ S.Hobbs"
(i]]i0)=1 (i]i0)=1 (i>i0)=0    b("12345678901234567874")="NotNum20 @ S.Hobbs"
(i]]i0)=1 (i]i0)=0 (i>i0)=1    b(1000000000000000000000000000000)=1
(i]]i0)=1 (i]i0)=1 (i>i0)=1    b(3000000000000000000000000000000)=3
(i]]i0)=1 (i]i0)=0 (i>i0)=1    b("100000000000000000000000000000011")=11
(i]]i0)=1 (i]i0)=1 (i>i0)=1    b("300000000000000000000000000000033")=33
(i]]i0)=1 (i]i0)=0 (i>i0)=1    b("1000000000000000000000000000000111")=111
(i]]i0)=1 (i]i0)=1 (i>i0)=1    b("3000000000000000000000000000000333")=333
(i]]i0)=1 (i]i0)=0 (i>i0)=0    b("10000000000000000000000000000001a")="3a"
(i]]i0)=1 (i]i0)=1 (i>i0)=1    b("30000000000000000000000000000001a")="4a"
...
Рейтинг: 0 / 0
10.06.2016, 13:57
| Ответить | Цитировать | Написать  
29 сообщений из 29, показаны все 2 страниц
  все  
Форумы / Caché, Ensemble, DeepSee, MiniM, IRIS, GT.M [игнор отключен] [закрыт для гостей] / Почему так сортируются строки?
Целевая тема:
Создать новую тему:
Автор:
Закрыть
Цитировать
Найденые пользователи ...
Разблокировать пользователей ...
Читали тему (0):
Читали форум (0):
Пользователи онлайн (0):
Польз. соглашение
NoSQL.ru             Фотоальбом: Участники, Встречи
Закрыть
start [/forum/topic.php?all=1&fid=39&tid=1556460]:
 0ms
get settings:
 9ms
get forum list:
 12ms
check forum access:
 4ms
check topic access:
 4ms
track hit:
 30ms
get topic data:
 12ms
get forum data:
 3ms
get page messages:
 57ms
get tp. blocked users:
 1ms
others: 14ms
total:  146ms
созд. / загр.: 146ms
x
x
Закрыть


Просмотр
0 / 0
Close
Debug Console [Select Text]