TIntArray = array of integer;
  TIntSet512Item = 0..511;
  TIntSet512 = record
  const
    LData = 63;
  var
    //TEnumSetType = set of Byte;
    FData: array [0..LData] of cardinal;
  private
    function GetAsSaveStr: string;
    procedure SetAsSaveStr(const Value: string);
  public
    procedure Clear;
    function IsEmpty: Boolean;
    procedure Include (AItem: TIntSet512Item); overload; inline;
    procedure Include (AItems: TIntArray); overload; inline;
    procedure Include (AItems: array of integer); overload;
    procedure Exclude (AItem: TIntSet512Item); overload; inline;
    procedure Exclude (AItems: TIntArray); overload; inline;
    function ToArray: TIntArray;

    class operator In (AItem: TIntSet512Item; const Value: TIntSet512): Boolean;
    class operator Equal (const L, R: TIntSet512) : Boolean;
    class operator NotEqual (const L, R: TIntSet512): Boolean;
    class operator Add (const L, R: TIntSet512): TIntSet512;
    class operator Add (const L: TIntSet512; R: TIntSet512Item): TIntSet512;
    class operator Subtract (const L, R: TIntSet512): TIntSet512;
    class operator Subtract (const L: TIntSet512; R: TIntSet512Item): TIntSet512;
    class operator Multiply (const L, R: TIntSet512): TIntSet512;

    procedure LoadJSON (const ATag: string; ANode: TJSONObject);
    procedure SaveJSON (const ATag: string; ANode: TJSONObject);

    property AsSaveStr: string read GetAsSaveStr write SetAsSaveStr;
  end;

{ TIntSet512 }

procedure TIntSet512.Clear;
begin
  FillChar (FData [0], sizeof(FData), #0);
end;

function TIntSet512.IsEmpty: Boolean;
var
  i: integer;
begin
  for i := 0 to LData do
    if FData [i] <> 0 then
      exit (false);
  Result := true;
end;

class operator TIntSet512.Equal(const L, R: TIntSet512): Boolean;
var
  i: integer;
begin
  for i := 0 to LData do
    if L.FData [i] <> R.FData [i] then
      exit (false);
  Result := true;
end;

class operator TIntSet512.NotEqual(const L, R: TIntSet512): Boolean;
begin
  Result := not (L = R);
end;

class operator TIntSet512.In(AItem: TIntSet512Item; const Value: TIntSet512): Boolean;
var
  i, j: word;
begin
  DivMod (AItem, 32, i, j);
  Result := (Value.FData [i] and (1 shl j)) <> 0;
end;

procedure TIntSet512.Include(AItem: TIntSet512Item);
var
  i, j: word;
begin
  DivMod (cardinal(AItem), 32, i, j);
  FData [i] := (FData [i] or (1 shl j));
end;

procedure TIntSet512.Exclude(AItem: TIntSet512Item);
var
  i, j: word;
begin
  DivMod (AItem, 32, i, j);
  FData [i] := (FData [i] and not (1 shl j));
end;

class operator TIntSet512.Add(const L: TIntSet512; R: TIntSet512Item): TIntSet512;
begin
  Result := L;
  Result.Include (R);
end;

class operator TIntSet512.Subtract(const L: TIntSet512; R: TIntSet512Item): TIntSet512;
begin
  Result := L;
  Result.Exclude (R);
end;

procedure TIntSet512.Include(AItems: TIntArray);
var
  i: integer;
begin
  for i := 0 to length (AItems)-1 do
    Include(AItems [i]);
end;

procedure TIntSet512.Include (AItems: array of integer);
var
  i: integer;
  Itm: TIntSet512Item;
begin
  for i := 0 to length (AItems)-1 do begin
    Itm := AItems [i];
    Include(Itm);
  end;
end;

procedure TIntSet512.Exclude(AItems: TIntArray);
var
  i: integer;
begin
  for i := 0 to length (AItems)-1 do
    Exclude(AItems [i]);
end;

class operator TIntSet512.Add(const L, R: TIntSet512): TIntSet512;
var
  i: integer;
begin
  for i := 0 to LData do
    Result.FData [i] := L.FData [i] or R.FData [i];
end;

class operator TIntSet512.Multiply(const L, R: TIntSet512): TIntSet512;
var
  i: integer;
begin
  for i := 0 to LData do
    Result.FData [i] := L.FData [i] and R.FData [i];
end;

class operator TIntSet512.Subtract(const L, R: TIntSet512): TIntSet512;
var
  i: integer;
begin
  for i := 0 to LData do
    Result.FData [i] := L.FData [i] and not R.FData [i];
end;

function TIntSet512.ToArray: TIntArray;
var
  i, j, Cnt: integer;
  D: cardinal;

  procedure Add (K: integer);
  var
    L: integer;
  begin
    L := length (Result);
    if Cnt >= L then
      SetLength (Result, L*2);
    Result [Cnt] := K;
    inc (Cnt);
  end;
begin
  SetLength (Result, 16);
  Cnt := 0;
  for i := 0 to LData do begin
    D := FData [i];
    if D = 0 then continue;
    for j := 0 to 31 do
      if (D and (1 shl j)) <> 0 then
        Add (i*32+j);
  end;
  SetLength (Result, Cnt);
end;

function TIntSet512.GetAsSaveStr: string;
var
  i, j: integer;
  S: string;
  D: cardinal;

   function CondSep (const Cond1, Sep, Cond2: string): string;
   begin
    if (Cond1 = '') or (Cond2 = '') then
      Result := Cond1 + Cond2
    else
      Result := Cond1 + Sep + Cond2;
   end;

begin
  Result := '';
  for i := 0 to LData do begin
    D := FData [i];
    if D = 0 then continue;

    S := '';

    for j := 0 to 31 do
      if (D and (1 shl j)) <> 0 then
        S := CondSep (S, ',', (i*32+j).ToString);
    Result := CondSep (Result, ',',  S);
  end;
end;

procedure TIntSet512.SetAsSaveStr(const Value: string);
var
  A: TStringArray;
  i, K: integer;
begin
  ExtractWords (Value, ',', A);
  Clear;
  for i := 0 to length (A)-1 do
    if TryStrToInt (A[i], K) then
      include (K);
end;

procedure TIntSet512.LoadJSON (const ATag: string; ANode: TJSONObject);
var
  A: TJSONArray;
  i, V: integer;
begin
  Clear;
  A := ANode.GetValue('ViewTypes') as TJSONArray;
  if A = nil then exit;
  for i := 0 to A.Count-1 do
    if TryStrToInt (A.Items [i].Value, V) then
      include (V);
end;

procedure TIntSet512.SaveJSON (const ATag: string; ANode: TJSONObject);
var
  A: TJSONArray;
  i, j: integer;
  D: cardinal;
begin
  if IsEmpty then exit;

  A := TJSONArray.Create;
  ANode.AddPair (ATag, A);

  for i := 0 to LData do begin
    D := FData [i];
    if D = 0 then continue;

    for j := 0 to 31 do
      if (D and (1 shl j)) <> 0 then
        A.Add ((i*32+j).ToString);
  end;
end;