program player;

{$WEAKLINKRTTI ON}

uses
  WinApi.MMSystem;

begin
  PlaySound('SOUND', HInstance, SND_RESOURCE or SND_NODEFAULT or SND_SYNC);
end.

PLAYER RCDATA "player.exe"

program Wav2Exe;

{$R 'player.res' 'player.rc'}

uses
  WinApi.Windows,
  System.SysUtils,
  System.Classes,
  System.IOUtils,
  Vcl.Dialogs;

var
  SoundFileName: string;
  PlayerFileName: string;
  PlayerStream: TResourceStream;
  OutFileStream: TFileStream;
  SoundFileData: TBytes;
  hSoundResource: THandle;
begin
  PlayerFileName := '';
  try
    with TOpenDialog.Create(nil) do try
      Title := 'Исходный звуковой файл';
      Filter := 'Звуковые файлы|*.wav|Все файлы|*.*';
      Options := [ofHideReadOnly, ofPathMustExist, ofFileMustExist, ofNoTestFileCreate];
      if not Execute(0) then Exit;
      SoundFileName := FileName;
    finally
      Free;
    end;
    with TOpenDialog.Create(nil) do try
      Title := 'Сохранить проигрыватель как';
      Filter := 'Исполняемые файлы|*.exe|Все файлы|*.*';
      Options := [ofOverwritePrompt, ofHideReadOnly];
      DefaultExt := 'exe';
      if not Execute(0) then Exit;
      PlayerFileName := FileName;
    finally
      Free;
    end;
    OutFileStream := nil;
    PlayerStream := TResourceStream.Create(HInstance, 'PLAYER', RT_RCDATA);
    try
      OutFileStream := TFile.Create(PlayerFileName);
      OutFileStream.CopyFrom(PlayerStream, PlayerStream.Size);
    finally
      OutFileStream.Free;
      PlayerStream.Free;
    end;
    SoundFileData := TFile.ReadAllBytes(SoundFileName);
    hSoundResource := BeginUpdateResource(PChar(PlayerFileName), True);
    try
      UpdateResource(hSoundResource, 'WAVE', 'SOUND', LANG_NEUTRAL,
        PByte(SoundFileData), Length(SoundFileData));
    finally
      EndUpdateResource(hSoundResource, False);
    end;
    MessageBox(0, 'Преобразование завершено успешно.', 'Wav2Exe',
      MB_ICONINFORMATION or MB_APPLMODAL or MB_OK);
  except
    on E: Exception do begin
      if (PlayerFileName <> '') and FileExists(PlayerFileName) then
        DeleteFile(PlayerFileName);
      MessageBox(0, PChar(E.ClassName + ': ' + E.Message), nil,
        MB_ICONERROR or MB_APPLMODAL or MB_OK);
    end;
  end;
end.