Private Sub Form_Load()

    SourceObject = ""
    nodeKey = ""
    Me!lstOption =  1 
    
    bExcel = Null
    sFileName = ""
    bFormat = Null
    bOpen = Null
    optFieldList = Null
    
    Call modCheckData.LoadTree(Me.treeCtl.Object, Me.lstOption)
    ' Key:="ROOT"
    ' Key:="CD" & rsCheckData!iCheckDataID
    ' Key:="OP" & rsNode!iSyntaxNodeID
    With Me.treeCtl.Nodes("ROOT")
        .Expanded = True
        .Selected = True
    End With
    NodeClick Me.treeCtl.Nodes("ROOT"), True

    With Me.treeCtl
        .style =  7 
        .Indentation =  300 
        .LineStyle =  1 
        .Visible = True
        .SetFocus
        .OLEDragMode =  1  ' ccOLEDragAutomatic
        .OLEDropMode =  1  ' ccOLEDropManual
    End With
    blnDragging = False

End Sub

Private Sub treeCtl_NodeClick(ByVal oNode As Object)

    NodeClick oNode, True

End Sub

Public Function SetDatasourceList()

    If SourceObject = "CheckData0" Then
        If Me.lstOption =  1  Then
            With Me.subForm.Form.sDatasourceName
                .RowSource = _
                    "SELECT sDatasourceName, sDatasourceDescription " & _
                    "FROM qrDatasourceDescription " & _
                    "ORDER BY sDatasourceName, sDatasourceDescription"
                .ColumnWidths = "2268;5670"
                .BoundColumn =  1 
            End With
        Else
            With Me.subForm.Form.sDatasourceName
                .RowSource = _
                    "SELECT sDatasourceDescription, sDatasourceName " & _
                    "FROM qrDatasourceDescription " & _
                    "ORDER BY sDatasourceDescription, sDatasourceName"
                .ColumnWidths = "5670;2268"
                .BoundColumn =  2 
            End With
        End If
    End If
    
End Function

Public Function NodeClick(n As node, Optional bVisualEffect As Boolean = True)

    DoCmd.Hourglass True
    If Not n Is Nothing Then
        nodeKey = n.Key
        Dim s As String, ss() As String
        s = n.FullPath
        ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 
            If SourceObject <> "CheckData0" Then
                SourceObject = "CheckData0"
                Me.subForm.SourceObject = "frmMETA_CheckData_subCheckData0"
                Me.subForm.Form.UniqueTable = "METAB_CheckData"
                Me.lblSub.Caption = " Проверочные отчеты"
            End If
            Me.subForm.Form.RecordSource = _
                "SELECT * " & _
                "FROM qrCheckData " & _
                "ORDER BY sCheckDataName"
            Call SetDatasourceList
        Case  1 
            If SourceObject <> "CheckData1" Then
                SourceObject = "CheckData1"
                Me.subForm.SourceObject = "frmMETA_CheckData_subCheckData1"
                Me.subForm.Form.UniqueTable = "METAB_CheckData"
                Me.lblSub.Caption = " Данные отчета"
            End If
            Me.subForm.Form.RecordSource = _
                "SELECT * " & _
                "FROM qrCheckData " & _
                "WHERE iCheckDataID=" & Mid(n.Key,  3 )
        Case Else
            If SourceObject <> "CheckData2" Then
                SourceObject = "CheckData2"
                Me.subForm.SourceObject = "frmMETA_CheckData_subCheckData2"
                Me.subForm.Form.UniqueTable = "METAB_SyntaxNode"
                Me.lblSub.Caption = " Данные узла"
            End If
            Me.subForm.Form.RecordSource = _
                "SELECT * " & _
                "FROM qrSyntaxNode " & _
                "WHERE iSyntaxNodeID=" & Mid(n.Key,  3 ) & " " & _
                "ORDER BY iSyntaxNodeParentNomer"
        End Select
    Else
        nodeKey = ""
    End If
    If Me.subForm.SourceObject <> "" Then
        Dim b As Boolean: b = modUser.IsSuperUser()
        With Me.subForm.Form
            .AllowAdditions = b
            .AllowDeletions = b
            .AllowEdits = b
        End With
    End If
    Form_Resize
    DoCmd.Hourglass False

End Function

Private Sub btnExpandAll_Click()

    DoCmd.Hourglass True
    Me.treeCtl.Visible = False
    Me.Repaint
    Me.Painting = False
    
    Dim n As node
    For Each n In Me.treeCtl.Nodes
        n.Expanded = True
    Next n

    Me.treeCtl.Visible = True
    Me.Painting = True
    DoCmd.Hourglass False

End Sub

Public Function CollapseAll()

    Dim n As node
    For Each n In Me.treeCtl.Nodes
        If n.Key = "ROOT" Then
            n.Expanded = True
        Else
            n.Expanded = False
        End If
    Next n

End Function

Public Function CollapseAllVisual()

    DoCmd.Hourglass True
    Me.treeCtl.Visible = False
    Me.Repaint
    Me.Painting = False
    
    Call CollapseAll
    
    Me.treeCtl.Visible = True
    Me.Painting = True
    DoCmd.Hourglass False

End Function

Private Sub btnCollapseAll_Click()

    Call CollapseAllVisual
    
End Sub

Private Sub btnChildOR_Click()

    Dim treeNode As node, id, idParent, sFlag, iLevel
    Set treeNode = Me.treeCtl.SelectedItem
    If Not treeNode Is Nothing Then
        Dim s As String, ss() As String
        s = treeNode.FullPath
        ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 ,  1 
            Beep
            Exit Sub
        Case Else
            iLevel =  2 
            id = CLng(Mid(treeNode.Key,  3 ))
            idParent = DLookup( _
                "iSyntaxNodeParentID", "METAB_SyntaxNode", _
                "iSyntaxNodeID=" & id)
            If Not IsNull(idParent) Then
                CurrentProject.Connection.Execute _
                    "dbo.SyntaxNode_MoveNodeToChild 'OR', " & id
            End If
        End Select
    End If
    
    If Not id >  0  Then
        Beep
        Exit Sub
    End If

End Sub

Private Sub btnChildAND_Click()

    Dim treeNode As node, id, idParent, sFlag, iLevel
    Set treeNode = Me.treeCtl.SelectedItem
    If Not treeNode Is Nothing Then
        Dim s As String, ss() As String
        s = treeNode.FullPath
        ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 ,  1 :
            Beep
            Exit Sub
        Case Else
            iLevel =  2 
            id = CLng(Mid(treeNode.Key,  3 ))
            idParent = DLookup( _
                "iSyntaxNodeParentID", "METAB_SyntaxNode", _
                "iSyntaxNodeID=" & id)
            If Not IsNull(idParent) Then
                CurrentProject.Connection.Execute _
                    "dbo.SyntaxNode_MoveNodeToChild 'AND', " & id
            End If
        End Select
    End If

End Sub

Private Sub btnCopy_Click()

    Dim treeNode As node, id, idCopy, sFlag
    Set treeNode = Me.treeCtl.SelectedItem
    If Not treeNode Is Nothing Then
        id = Null
        Dim s As String: s = treeNode.FullPath
        Dim ss() As String: ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 ,  1 
            Call modForm.GetObjectID(Me.subForm.Form, "iCheckDataID", id)
            If Not IsNull(id) Then
                CurrentProject.Connection.Execute _
                    "dbo.CheckData_CopyTree " & id
            End If
        Case Else
            'Данные текущего уровня
            id = CLng(Mid(treeNode.Key,  3 ))
            sFlag = DLookup( _
                    "sSyntaxNodeRootFlag", "METAB_SyntaxNode", _
                    "iSyntaxNodeID=" & id)
            If id >  0  Then
                idCopy = CurrentProject.Connection.Execute _
                    ("dbo.SyntaxNode_CopyNode " & id).Fields("iSyntaxNodeID")
                If idCopy >  0  Then
                    ' Key:="OP" & rsNode!iSyntaxNodeID
                    RequeryTree
                    Set treeNode = Me.treeCtl.Nodes("OP" & idCopy)
                    Call modTree.ExpandNode(Me.treeCtl.Object, treeNode, True)
                    Call Me.NodeClick(treeNode)
                End If
            End If
        End Select
    End If

End Sub

Private Sub btnDelete_Click()

    Dim treeNode As node, id, sFlag
    Set treeNode = Me.treeCtl.SelectedItem
    If Not treeNode Is Nothing Then
        id = Null
        Dim s As String: s = treeNode.FullPath
        Dim ss() As String: ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 ,  1 
            '   Удаление всего отчета
            Call modForm.GetObjectID(Me.subForm.Form, "iCheckDataID", id)
            If Not IsNull(id) Then
                On Error Resume Next
                CurrentProject.Connection.Execute _
                    "dbo.CheckData_DeleteTree " & id
                If Err.number <>  0  Then
                    '   -2147217873
                    '   DELETE statement conflicted with COLUMN REFERENCE constraint
                    '   'FK_METAB_CheckDataSchedule_METAB_CheckData'.
                    '   The conflict occurred in database 'AM',
                    '   table 'METAB_CheckDataSchedule', column 'iCheckDataID'.
                    If Err.number = - 2147217873  Then
                        MsgBox _
                            "Нельзя удалить данный проверочный отчет, " & _
                            "так как он используется в системе.", _
                            vbExclamation + vbOKOnly, _
                            "Удаления проверочного отчета"
                    End If
                    Err.Clear
                    GoTo exit_sub
                End If
                On Error GoTo  0 
            End If
        Case Else
            '   Данные текущего уровня дерева выражений
            id = CLng(Mid(treeNode.Key,  3 ))
            sFlag = DLookup( _
                    "sSyntaxNodeRootFlag", "METAB_SyntaxNode", _
                    "iSyntaxNodeID=" & id)
            If id >  0  Then
                CurrentProject.Connection.Execute _
                    "dbo.SyntaxNode_DeleteNode " & id
            End If
        End Select
        Me.treeCtl.Nodes.Remove treeNode.Key
    End If
    
exit_sub:
    Exit Sub

End Sub

Private Sub btnMoveUp_Click()

    Dim treeNode As node, id, idParent, sFlag, iLevel
    Set treeNode = Me.treeCtl.SelectedItem
    If Not treeNode Is Nothing Then
        Dim s As String, ss() As String
        s = treeNode.FullPath
        ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 ,  1 
            Beep
            Exit Sub
        Case Else
            iLevel =  2 
            id = CLng(Mid(treeNode.Key,  3 ))
            idParent = DLookup( _
                "iSyntaxNodeParentID", "METAB_SyntaxNode", _
                "iSyntaxNodeID=" & id)
            If Not IsNull(idParent) Then
                CurrentProject.Connection.Execute _
                    "dbo.SyntaxNode_MoveNodeToParent " & id
            End If
        End Select
    End If

End Sub

Public Function RequeryTree()

    Dim s As String
    s = Me.treeCtl.SelectedItem.Key
    Me.treeCtl.Nodes.Clear
    DoCmd.Hourglass True
    Me.treeCtl.Visible = False
    Me.subForm.Visible = False
    Me.Repaint
    Me.Painting = False
    
    Call modCheckData.LoadTree(Me.treeCtl.Object, Me.lstOption, False)
    CollapseAll
    Me.subForm.Form.Requery
    On Error Resume Next
    Me.treeCtl.Nodes(s).Selected = True
    Me.treeCtl.Nodes(s).EnsureVisible = True
    On Error GoTo  0 

    If SourceObject = "CheckData0" Then Call SetDatasourceList

set_focus:
    Me.subForm.Visible = True
    Me.treeCtl.Visible = True
    Me.treeCtl.SetFocus
    Me.Painting = True
    DoCmd.Hourglass False
    Exit Function
    
err_label:
    If Err.number =  35601  Then
        'Element not found
        Err.Clear
        Resume set_focus
    End If

End Function

Private Sub btnRequery_Click()

    RequeryTree
    
End Sub

Private Sub lstOption_AfterUpdate()

    RequeryTree

End Sub

Public Function CheckDataLevel()

    Dim treeNode As node, id, sFlag
    Set treeNode = Me.treeCtl.SelectedItem
    Me.treeCtl.SetFocus
    If Not treeNode Is Nothing Then
        Dim s As String, ss() As String
        s = treeNode.FullPath
        ss = Split(s, "\")
        Select Case UBound(ss)
        Case  0 ,  1 
            Call modForm.GetObjectID(Me.subForm.Form, "iCheckDataID", id)
        Case Else
            id = CLng(Mid(treeNode.Key,  3 ))
            sFlag = DLookup( _
                "sSyntaxNodeRootFlag", "METAB_SyntaxNode", _
                "iSyntaxNodeID=" & id)
            While sFlag <> "Y" And Not IsNull(id)
                id = DLookup( _
                    "iSyntaxNodeParentID", "METAB_SyntaxNode", _
                    "iSyntaxNodeID=" & id)
                sFlag = DLookup( _
                    "sSyntaxNodeRootFlag", "METAB_SyntaxNode", _
                    "iSyntaxNodeID=" & id)
            Wend
            If Not IsNull(id) Then
                id = DLookup( _
                    "iSyntaxNodeParentID", "METAB_SyntaxNode", _
                    "iSyntaxNodeID=" & id)
                Set treeNode = Me.treeCtl.Nodes("CD" & id)
            End If
        Me.treeCtl.Nodes("CD" & id).Selected = True
        Call NodeClick(treeNode)
        Me.subForm.Form.Requery
        If id >  0  Then Me.subForm.Form.Recordset.Find "iCheckDataID=" & id
        End Select
    End If
    
    CheckDataLevel = id
    Exit Function

End Function

Private Sub btnExecute_Click()
    
    Dim id: id = CheckDataLevel
    If Not id >  0  Then Beep: Exit Sub
    
    Dim rs As New ADODB.Recordset
    Set rs = Me.subForm.Form.Recordset
        
    If Not rs.EOF And Not rs.BOF Then
        Dim sCheckDataSQL_OUT As String, sCheckDataOrderBy_OUT As String, sFieldList_OUT As String
        Dim sCheckDataRunUserName_OUT As String, dtCheckDataRunDate_OUT As Date
        Dim nCheckDataRunRecordCount_OUT As Integer
        
        Dim n: n = modCheckData.ParseAndRun( _
            rs!sDatasourceName, rs!iCheckDataID, rs!bCheckDataIncludeAudit, _
            sFieldList_OUT, sCheckDataSQL_OUT, sCheckDataOrderBy_OUT, _
            sCheckDataRunUserName_OUT, dtCheckDataRunDate_OUT, _
            nCheckDataRunRecordCount_OUT)
        Select Case n
        Case - 1 
            DoCmd.Hourglass False: Beep
            MsgBox _
                "Проверочный отчет " & rs!sCheckDataName & _
                vbNewLine & vbNewLine & _
                "Не выполнен из-за неверно сгенерированных условий проверки " & _
                "или по другой причине, связанной с исполнением инструкций SQL.", _
                vbExclamation + vbOKOnly
            DoCmd.Hourglass True
        Case - 2 
            DoCmd.Hourglass False: Beep
            MsgBox _
                "Проверочный отчет " & rs!sCheckDataName & _
                vbNewLine & vbNewLine & _
                "Не задан источник данных.", vbExclamation + vbOKOnly
            DoCmd.Hourglass True
        Case - 3 
            DoCmd.Hourglass False: Beep
            MsgBox _
                "Проверочный отчет " & rs!sCheckDataName & _
                vbNewLine & vbNewLine & _
                "Не сгенерирован текст условия отбора.", _
                vbExclamation + vbOKOnly
            DoCmd.Hourglass True
        Case Is >=  0 
            If n =  0  Then
                Beep
                MsgBox _
                    "Проверка выполнена успешно. " & vbNewLine & vbNewLine & _
                    "По условиям проверки не отфильтровано ни одной записи в источника данных.", _
                    vbInformation + vbOKOnly
            Else
                Beep
                sFileName = rs!sCheckDataName
                Dim sTableFormName: sTableFormName = DLookup( _
                    "sTableFormName", "TAB_DatasourceDescription", _
                    "sDatasourceName='" & rs!sDatasourceName & "'")
                Dim s
                If Len(sTableFormName) >  0  Then
                    s = modCheckDataRun.CheckDataOption _
                    (bExcel, sFileName, bFormat, bOpen, optFieldList,  1 )
                Else
                    s = modCheckDataRun.CheckDataOption _
                    (bExcel, sFileName, bFormat, bOpen, optFieldList,  0 )
                End If
                If InStr( 1 , s, "TABLE") >  0  Then
                    Dim sOpenArgs
                    sOpenArgs = _
                        "CheckData=" & sCheckDataSQL_OUT & ";" & _
                        "FieldList=" & sFieldList_OUT
                    DoCmd.OpenForm _
                        sTableFormName, acNormal, , , acFormEdit, acWindowNormal, _
                        sOpenArgs
                End If
                If InStr( 1 , s, "EXCEL") >  0  Then
                    DoCmd.OpenForm _
                        "dlgCheckDataProgress", _
                        acNormal, , , acFormEdit, acWindowNormal
                    Dim dlg As Form_dlgCheckDataProgress
                    Set dlg = Forms("dlgCheckDataProgress")
                    dlg.lbl1.Caption = "Проверочный отчет " & vbNewLine & vbNewLine & rs!sCheckDataName
                    modCheckDataRun.ExportCheckToXLS _
                        bFormat, bOpen, optFieldList, rs!bCheckDataIncludeAudit, _
                        sFileName, rs!sDatasourceName, _
                        rs!iCheckDataID, rs!sCheckDataName, _
                        rs!sCheckDataSQL, rs!sCheckDataOrderBy, _
                        dtCheckDataRunDate_OUT, sCheckDataRunUserName_OUT, _
                        nCheckDataRunRecordCount_OUT
                    DoCmd.Close acForm, "dlgCheckDataProgress", acSaveNo
                    On Error Resume Next
                    Dim xl As Object: Set xl = CreateObject("Excel.Application")
                    xl.DisplayAlerts = True
                    xl.Workbooks.Open sFileName
                    xl.Visible = True
                    Set xl = Nothing
                    On Error GoTo  0 
                End If
            End If
        End Select
    End If
    Set rs = Nothing
    
End Sub

Private Sub btnExecuteAll_Click()

    Dim nRoot As node, id, sFlag
    Set nRoot = Me.treeCtl.Nodes("ROOT")
    NodeClick nRoot, True
    Me.treeCtl.SetFocus
    
    DoCmd.Hourglass True
    Dim rs As ADODB.Recordset
    Set rs = Me.subForm.Form.RecordsetClone
    If Not rs.EOF And Not rs.BOF Then
        rs.MoveFirst
        While Not rs.EOF
            Dim sCheckDataSQL_OUT As String, sCheckDataOrderBy_OUT As String, sFieldList_OUT As String
            Dim sCheckDataRunUserName_OUT As String, dtCheckDataRunDate_OUT As Date
            Dim nCheckDataRunRecordCount_OUT As Integer
            Dim n: n = modCheckData.ParseAndRun( _
                rs!sDatasourceName, rs!iCheckDataID, rs!bCheckDataIncludeAudit, _
                sFieldList_OUT, sCheckDataSQL_OUT, sCheckDataOrderBy_OUT, _
                sCheckDataRunUserName_OUT, dtCheckDataRunDate_OUT, _
                nCheckDataRunRecordCount_OUT)
            Select Case n
            Case - 1 
                DoCmd.Hourglass False: Beep
                MsgBox _
                    "Проверочный отчет " & rs!sCheckDataName & _
                    vbNewLine & vbNewLine & _
                    "Не выполнен из-за неверно сгенерированных условий проверки " & _
                    "или по другой причине, связанной с исполнением инструкций SQL.", _
                    vbExclamation + vbOKOnly
                DoCmd.Hourglass True
            Case - 2 
                DoCmd.Hourglass False
                Beep
                MsgBox _
                    "Проверочный отчет " & rs!sCheckDataName & _
                    vbNewLine & vbNewLine & _
                    "Не задан источник данных.", vbExclamation + vbOKOnly
                DoCmd.Hourglass True
            Case - 3 
                DoCmd.Hourglass False
                Beep
                MsgBox _
                    "Проверочный отчет " & rs!sCheckDataName & _
                    vbNewLine & vbNewLine & _
                    "Не сгенерирован текст условия отбора.", vbExclamation + vbOKOnly
                DoCmd.Hourglass True
            Case Is >=  0 
            End Select
            rs.MoveNext
        Wend
        rs.MoveLast
    End If
    Set rs = Nothing
    DoCmd.Hourglass False
    
    Exit Sub
    
End Sub

Private Sub btnCheckDataSchedule_Click()

    DoCmd.OpenForm "frmMETA_CheckDataSchedule", acNormal, , , acFormEdit, acWindowNormal

End Sub

Private Sub treeCtl_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal x As Long, ByVal y As Long)

    Dim nodNode As node
    ' get the node we are over
    Set nodNode = Me.treeCtl.HitTest(x, y)
    If nodNode Is Nothing Then Exit Sub ' no node
    ' ensure node is actually selected, just incase we start dragging.
    nodNode.Selected = True
    
End Sub

' occurs when the user starts dragging
' this is where you assign the effect and the data.
Private Sub treeCtl_OLEStartDrag(Data As Object, AllowedEffects As Long)

'ccOLEDropEffectCopy = 1
'ccOLEDropEffectMove = 2
'ccOLEDropEffectNone = 0
'ccOLEDropEffectScroll = -2147483648 (&H80000000)

    ' Set the effect to move
    AllowedEffects =  2  'MSComctlLib.OLEDropEffectConstants.ccOLEDropEffectMove
    ' Assign the selected item's key to the DataObject
    Data.SetData Me.treeCtl.SelectedItem.Key
    ' we are dragging from this control
    blnDragging = True
    
End Sub

' occurs when the object is dragged over the control.
' this is where you check to see if the mouse is over
' a valid drop object
Private Sub treeCtl_OLEDragOver(Data As Object, Effect As Long, Button As Integer, Shift As Integer, x As Single, y As Single, State As Integer)

    Dim nodNode As node
    ' set the effect
    Effect =  2  'MSComctlLib.OLEDropEffectConstants.ccOLEDropEffectMove
    ' get the node that the object is being dragged over
    Set nodNode = Me.treeCtl.HitTest(x, y)
    If nodNode Is Nothing Then
        Effect =  0  'MSComctlLib.OLEDropEffectConstants.ccOLEDropEffectNone
        Exit Sub
    End If
    If _
        nodNode.Key = "ROOT" Or Left(nodNode.Key,  2 ) = "CD" Or _
        blnDragging = False _
    Then
        ' the dragged object is not over a node, invalid drop target
        ' or the object is not from this control.
        Effect =  0  'MSComctlLib.OLEDropEffectConstants.ccOLEDropEffectNone
        Exit Sub
    End If
    
End Sub

' occurs when the user drops the object
' this is where you move the node and its children.
' this will not occur if Effect = vbDropEffectNone
Private Sub treeCtl_OLEDragDrop(Data As Object, Effect As Long, Button As Integer, Shift As Integer, x As Single, y As Single)

    Dim strSourceKey As String, idSource As Long
    Dim nodTarget As node, idTarget As Long
    ' get the carried data
    strSourceKey = Data.GetData( 1 )
    ' get the target node
    Set nodTarget = Me.treeCtl.HitTest(x, y)
    If _
        nodTarget Is Nothing Or _
        nodTarget.Key = "ROOT" Or _
        Left(nodTarget.Key,  2 ) = "CD" _
        Or blnDragging = False _
    Then
        Effect =  0 
        Beep
        Exit Sub
    End If
    idTarget = CLng(Mid(nodTarget.Key,  3 ))
    idSource = CLng(Mid(strSourceKey,  3 ))
    If idTarget = idSource Then
        Effect =  0 
        Beep
        Exit Sub
    End If
    ' if the target node is not a folder or the root item
    ' then get it's parent (that is a folder or the root item)
    ' move the source node to the target node
    Set Me.treeCtl.Nodes(strSourceKey).Parent = nodTarget
    CurrentProject.Connection.Execute _
        "UPDATE dbo.METAB_SyntaxNode " & _
        "SET " & _
            "iSyntaxNodeParentID=" & idTarget & ", " & _
            "iSyntaxNodeParentNomer=(" & _
                "SELECT MAX(iSyntaxNodeParentNomer) " & _
                "FROM dbo.METAB_syntaxNode " & _
                "WHERE iSyntaxNodeParentID=" & idTarget & _
            ") + 1 " & _
        "WHERE iSyntaxNodeID=" & idSource
    Me.subForm.Requery
    ' NOTE: You will also need to update the key to reflect the changes
    ' if you are using it
    ' we are not dragging from this control any more
    blnDragging = False
    ' cancel effect so that VB doesn't muck up your transfer
    Effect =  0 
    
End Sub