Private Sub Form_Timer()

    Me.TimerInterval =  0 : Me.OnTimer = ""

    'Загрузка списков огранизаций для данной роли
    modSYS.SetList Me!lstSort, "CustomerOrderBy"
    modSYS.SetList Me!lstFilter, "CustomerFilter"
    Me!optFilter = False
    Me!optFilter.Enabled = False
    Me!btnQuickFind.Enabled = False
    
    Dim id, s
    If modForm.GetObjectByArgs("CheckData", Me.OpenArgs, s) Then
        Me!lstFilter.Enabled = False
        Me!btnAddCustomer.Enabled = False
        Me!btnDeleteCustomer.Enabled = False
    End If
    If modForm.GetObjectByArgs("iCustomerTypeID", Me.OpenArgs, id) Then
        Me!lstFilter = id
    End If

    'А внутри данной ф-ии грузится сам источник формы.
    Call RequeryData
    
    Dim ctl As Control
    If modForm.GetObjectByArgs("FieldList", Me.OpenArgs, s) Then
        For Each ctl In Me!grData.Form.Controls
            If _
                ctl.ControlType = acCheckBox Or _
                ctl.ControlType = acComboBox Or _
                ctl.ControlType = acTextBox _
            Then
                If ctl.ColumnOrder > Me!grData.Form.FrozenColumns Then
                    If InStr( 1 , s, ctl.ControlSource) >  0  Then
                        ctl.ColumnHidden =  0 
                    Else
                        ctl.ColumnHidden = - 1 
                    End If
                End If
            End If
        Next ctl
    Else
        For Each ctl In Me!grData.Form.Controls
            If _
                ctl.ControlType = acCheckBox Or _
                ctl.ControlType = acComboBox Or _
                ctl.ControlType = acTextBox _
            Then
                If ctl.ColumnOrder > Me!grData.Form.FrozenColumns Then
                    ctl.ColumnHidden =  0 
                End If
            End If
        Next ctl
    End If
    
    Me!grData.Visible = True
    Me.Repaint

    Call modForm.FindObjectByArgs(Me!grData.Form, "iCustomerID", Me.OpenArgs)

    Set DataGrid = Me!grData.Form
    DataGrid.OnDblClick = "[Event Procedure]"
    DataGrid.OnCurrent = "[Event Procedure]"
    
End Sub

Public Function MakeWhere() As String

    MakeWhere = ""
    If Me!optFilter Then
        If Me!txtQuickFind.value <> "" Then
            MakeWhere = _
                "(sCustomerName LIKE '%" & Me!txtQuickFind.value & "%' OR " & _
                "sCustomerReportName LIKE '%" & Me!txtQuickFind.value & "%' OR " & _
                "sCustomerFullName LIKE '%" & Me!txtQuickFind.value & "%')"
        End If
    End If

    Dim s
    If modForm.GetObjectByArgs("CheckData", Me.OpenArgs, s) Then
        If Len(MakeWhere) >  0  Then MakeWhere = MakeWhere & " AND "
        MakeWhere = MakeWhere & s
    ElseIf Not IsNull(Me!lstFilter) Then
        Dim sWhere
        sWhere = Me!lstFilter.Column( 2 )
        If InStr( 1 , sWhere, "{LIST}") >  0  Then
            sWhere = Replace(sWhere, "{LIST}", Me!lstFilter)
        End If
        If Len(MakeWhere) >  0  Then MakeWhere = MakeWhere & " AND "
        MakeWhere = MakeWhere & sWhere
    End If
    
End Function

Public Function MakeOrderBy() As String

    MakeOrderBy = ""
    If Not IsNull(Me!lstSort) Then
        MakeOrderBy = Me!lstSort.Column( 2 )
    Else
        MakeOrderBy = ""
    End If
    
End Function

Public Function MakeSQL() As String
On Error GoTo err_label

    Dim sWhere As String, sOrderBy As String
    Dim sFormWhere As String, sFormSource As String, sFormOrderBy As String
    Dim sControlWhere As String, sControlOrderBy As String
    
    sWhere = ""
    sOrderBy = ""
    ' Внутри этой ф-ии проверяются пользователь и роль. Исходный код у тебя есть.
    modSYS.FormInfo "Customer", sFormSource, sFormWhere, sFormOrderBy
    sControlWhere = MakeWhere
    sControlOrderBy = MakeOrderBy
    
    If Len(sFormWhere) >  0  Then
        sWhere = "(" & sFormWhere & ")"
    End If
    If Len(sControlWhere) >  0  Then
        If Len(sWhere) >  0  Then
            sWhere = sWhere & " AND "
        End If
        sWhere = sWhere & "(" & sControlWhere & ")"
    End If
    
    If Len(sControlOrderBy) >  0  Then
        sOrderBy = sControlOrderBy
    Else
        If Len(sFormOrderBy) >  0  Then
            If Len(sOrderBy) >  0  Then
                sOrderBy = sOrderBy & ", "
            End If
            sOrderBy = sOrderBy & sFormOrderBy
        End If
    End If
    
    If Len(sWhere) >  0  Then sWhere = "WHERE " & sWhere
    If Len(sOrderBy) >  0  Then sOrderBy = "ORDER BY " & sOrderBy
    MakeSQL = "SELECT * FROM " & sFormSource & " " & sWhere & " " & sOrderBy
    
exit_label:
    Exit Function
err_label:
    Call modError.ErrorMessage(Err.number, Err.Description)
    Resume exit_label

End Function

Public Function RequeryData()
On Error GoTo err_label

    DoCmd.Hourglass True
    Me!lstSort.SetFocus
    Me!grData.Visible = False
    Me.Repaint: Me.Painting = False:

    With Me!grData.Form
        .RecordSource = MakeSQL
        Me!btnOpenForm.Enabled = .Recordset.RecordCount >  0  _
            And Not .Recordset.BOF And Not .Recordset.EOF
    End With
    DoEvents
    
    Me!grData.Visible = True
    Me!grData.SetFocus
    Me.Painting = True: DoCmd.Hourglass False

exit_label:
    DoCmd.Hourglass False
    Exit Function
err_label:
    Call modError.ErrorMessage(Err.number, Err.Description)
    Resume exit_label
    
End Function