FUNCTION GetMd5Hash  && Получение Хеш пароля с помощью алгоритма MD5
    LPARAMETERS tcInput
    #DEFINE dnPROV_RSA_FULL  1 
    #DEFINE dnCALG_MD5      0x8003
    #DEFINE dnHP_HASHVAL    0x0002
    DECLARE INTEGER CryptAcquireContext IN WIN32API INTEGER @, STRING, STRING, INTEGER, INTEGER
    DECLARE INTEGER CryptCreateHash IN WIN32API INTEGER, INTEGER, INTEGER, INTEGER, INTEGER @
    DECLARE INTEGER CryptHashData IN WIN32API INTEGER, STRING, INTEGER, INTEGER
    DECLARE INTEGER CryptGetHashParam IN WIN32API INTEGER, INTEGER, STRING @, INTEGER @, INTEGER
    DECLARE INTEGER CryptDestroyHash IN WIN32API INTEGER
    DECLARE INTEGER CryptReleaseContext IN WIN32API INTEGER, INTEGER
    LOCAL lnProviderHandle, lnHashHandle, lcHash, lnHashLen
    lnProviderHandle =  0 
    lnHashHandle =  0 
    lcHash = SPACE( 16 )
    lnHashLen =  16 
    IF CryptAcquireContext(@m.lnProviderHandle, "", "", dnPROV_RSA_FULL, 0xF0000000) =  0 
      ERROR "Ошибка получения CryptoAPI контекста"
      RETURN ""
    ENDIF
    IF CryptCreateHash(m.lnProviderHandle, dnCALG_MD5,  0 ,  0 , @m.lnHashHandle) =  0 
      ERROR "Ошибка создания хендла хеша"
      CryptReleaseContext(m.lnProviderHandle,  0 )
      RETURN ""
    ENDIF
    IF CryptHashData(m.lnHashHandle, m.tcInput, LEN(m.tcInput),  0 ) =  0 
      ERROR "Ошибка хеширования"
      CryptDestroyHash(m.lnHashHandle)
      CryptReleaseContext(m.lnProviderHandle,  0 )
      RETURN ""
    ENDIF
    IF CryptGetHashParam(m.lnHashHandle, dnHP_HASHVAL, @m.lcHash, @m.lnHashLen,  0 ) =  0 
      ERROR "Ошибка получения хеша"
      CryptDestroyHash(m.lnHashHandle)
      CryptReleaseContext(m.lnProviderHandle,  0 )
      RETURN ""
    ENDIF
    CryptDestroyHash(m.lnHashHandle)
    CryptReleaseContext(m.lnProviderHandle,  0 )
    RETURN LOWER(STRCONV(m.lcHash,  15 ))
  ENDFUNC