m.lcCommand = [SELECT UO_ID, UO_KOD, UO_NAME, Fasovka_ID, F_Obos, EI_ID, Obos, ] + ;
[SUM(Kvo) AS Kvo, SUM(KvoIn) AS KvoIn, AVG(ZenaPart) AS ZenaPart, ] + ;
[SUM(KvoP) AS KvoP, SUM(KvoR) AS KvoR, SUM(SumR) AS SumR, SUM(ZenaPart*KvoIn) AS SummPart ]
m.lcGroupBy = [ GROUP BY UO_ID, Fasovka_ID ]
IF .chkAkzis.Value
*-- Группировать по акцизу партии
m.lcCommand = m.lcCommand + [, Part_Akzis]
m.lcGroupBy = m.lcGroupBy + [, Part_Akzis]
ELSE
m.lcCommand = m.lcCommand + [,  0  AS Part_Akzis]
ENDIF
IF ListPodraz.Podr_ID =  0 	&& Все подразделения
m.lcCommand = m.lcCommand + [,  0  AS Podr_ID, 'ВСЕ' AS Podr_Name,  0  AS Mesto_ID, 'ВСЕ' AS Mesto_Name]
ELSE
*-- Не все подразделения
m.lcCommand = m.lcCommand + [, Podr_ID, Podr_Name]
IF .chkPodraz.Value
*-- Выбирать и все подчиненные подразделения. В этом случае группировка по местам
*-- хранения не выполняется
m.lcCommand = m.lcCommand + [,  0  AS Mesto_ID, 'ВСЕ' AS Mesto_Name]
m.lcOldPodrString = oApp.PodrString
*-- В курсоре tempp получаем список подразделений,
*-- подчиненных ListPodraz.Podr_ID (включительно)
GetPodraz("tempp", ListPodraz.Podr_ID)
oApp.PodrString = m.lcOldPodrString
m.lcWhere = m.lcWhere + [ AND (Podr_ID IN (SELECT Podr_ID FROM tempp))]
m.lcGroupBy = m.lcGroupBy + [, Podr_ID]
ELSE
IF ListMesto.Mesto_ID >  0 
*-- Только требуемое место хранения
m.lcCommand = m.lcCommand + [, Mesto_ID, Mesto_Name]
m.lcWhere = m.lcWhere + [ AND (Mesto_ID=] + ALLTRIM(STR(ListMesto.Mesto_ID)) + [) AND (Podr_ID=] +  ALLTRIM(STR(ListPodraz.Podr_ID)) + [)]
ELSE
*-- Все места хранения
*-- Надо разбирать по местам хранения?
IF .chkMesta.Value
m.lcCommand = m.lcCommand + [, Mesto_ID, Mesto_Name]
m.lcGroupBy = m.lcGroupBy + [, Podr_ID, Mesto_ID]
ELSE
m.lcCommand = m.lcCommand + [,  0  AS Mesto_ID, 'ВСЕ' AS Mesto_Name]
m.lcGroupBy = m.lcGroupBy + [, Podr_ID]				
ENDIF
USE IN SELECT("tempm")
CREATE CURSOR tempm (Mesto_ID I, Podr_ID I)
THISFORM.RSprav.GetMesto(ListPodraz.Podr_ID,  0 , "tempm2")
INSERT INTO tempm (Podr_ID, Mesto_ID) ;
SELECT Podr_ID, Mesto_ID FROM tempm2
USE IN tempm2
m.lcWhere = m.lcWhere + [ AND (Mesto_ID IN (SELECT Mesto_ID FROM tempm))]
ENDIF
ENDIF
ENDIF
IF .chkUpakovka.Value
m.lcCommand = m.lcCommand + [,  0  AS Upakovka_ID, 'ВСЕ' AS U_obos]
ELSE
m.lcCommand = m.lcCommand + [, Upakovka_ID, U_obos]
m.lcGroupBy = m.lcGroupBy + [, Upakovka_ID]
ENDIF
IF .chkOSN.Value
m.lcCommand = m.lcCommand + [, OSN_ID, OSN]
m.lcGroupBy = m.lcGroupBy + [, OSN_ID]
ELSE
m.lcCommand = m.lcCommand + [,  0  AS OSN_ID, 'ВСЕ СЧЕТА' AS OSN]
ENDIF
IF !(.txtSelAccountSint.Value =="*")	&& Не все счета
m.lcWhere = m.lcWhere + [ AND (] + ALLTRIM(.txtSelAccountSint.LikeMaskaSQL) + [)]
ENDIF
*-- Собираем всю команду
m.lcCommand = m.lcCommand + [ FROM lOborot INTO CURSOR temp NOFILTER READWRITE ] +m.lcWhere + m.lcGroupBy
*-- Выполняем
&lcCommand